mirror of
https://github.com/php/php-src.git
synced 2025-08-17 06:28:50 +02:00
52dba99d47
This syncs the installed sapi and extension headers on *nix and Windows systems by installing only what is intended outside of php-src. - ext/gd: without gd_arginfo.h and gd_compat.h - ext/hash: php_hash_joaat.h and php_hash_fnv.h added also on Windows installation; xxhash/xxhash.h added on both installations as it is included in php_hash_xxhash.h; Include path for xxhash.h changed to relative so the php_hash_xxhash.h can be included outside of php-src; Redundant include flags removed - ext/iconv: without iconv_arginfo.h - ext/mysqli: mysqli_mysqlnd.h was missing on Windows - ext/phar: php_phar.h was missing on Windows - ext/sodium: php_libsodium.h was missing on *nix - ext/xml: without xml_arginfo.h - sapi/cli: cli.h was missing on Windows Closes GH-13210 Closes GH-13213
43 lines
1.3 KiB
Text
43 lines
1.3 KiB
Text
PHP_ARG_ENABLE([session],
|
|
[whether to enable PHP sessions],
|
|
[AS_HELP_STRING([--disable-session],
|
|
[Disable session support])],
|
|
[yes])
|
|
|
|
PHP_ARG_WITH([mm],
|
|
[for mm support],
|
|
[AS_HELP_STRING([[--with-mm[=DIR]]],
|
|
[SESSION: Include mm support for session storage])],
|
|
[no],
|
|
[no])
|
|
|
|
if test "$PHP_SESSION" != "no"; then
|
|
PHP_PWRITE_TEST
|
|
PHP_PREAD_TEST
|
|
PHP_NEW_EXTENSION(session, mod_user_class.c session.c mod_files.c mod_mm.c mod_user.c, $ext_shared,, -DZEND_ENABLE_STATIC_TSRMLS_CACHE=1)
|
|
PHP_ADD_EXTENSION_DEP(session, hash, true)
|
|
PHP_ADD_EXTENSION_DEP(session, spl)
|
|
PHP_SUBST(SESSION_SHARED_LIBADD)
|
|
PHP_INSTALL_HEADERS([ext/session], [php_session.h mod_files.h mod_user.h])
|
|
AC_DEFINE(HAVE_PHP_SESSION,1,[ ])
|
|
fi
|
|
|
|
if test "$PHP_MM" != "no"; then
|
|
for i in $PHP_MM /usr/local /usr; do
|
|
test -f "$i/include/mm.h" && MM_DIR=$i && break
|
|
done
|
|
|
|
if test -z "$MM_DIR" ; then
|
|
AC_MSG_ERROR(cannot find mm library)
|
|
fi
|
|
|
|
if test "$PHP_THREAD_SAFETY" = "yes"; then
|
|
dnl The mm library is not thread-safe, and mod_mm.c refuses to compile.
|
|
AC_MSG_ERROR(--with-mm cannot be combined with --enable-zts)
|
|
fi
|
|
|
|
PHP_ADD_LIBRARY_WITH_PATH(mm, $MM_DIR/$PHP_LIBDIR, SESSION_SHARED_LIBADD)
|
|
PHP_ADD_INCLUDE($MM_DIR/include)
|
|
PHP_INSTALL_HEADERS([ext/session], [mod_mm.h])
|
|
AC_DEFINE(HAVE_LIBMM, 1, [Whether you have libmm])
|
|
fi
|