mirror of
https://github.com/php/php-src.git
synced 2025-08-21 01:45:16 +02:00
4371945b8b
Autoconf 2.50 released in 2001 made several macros obsolete including the AC_TRY_RUN, AC_TRY_COMPILE and AC_TRY_LINK: http://git.savannah.gnu.org/cgit/autoconf.git/tree/ChangeLog.2 These macros should be replaced with the current AC_FOO_IFELSE instead: - AC_TRY_RUN with AC_RUN_IFELSE and AC_LANG_SOURCE - AC_TRY_LINK with AC_LINK_IFELSE and AC_LANG_PROGRAM - AC_TRY_COMPILE with AC_COMPILE_IFELSE and AC_LANG_PROGRAM PHP 5.4 to 7.1 require Autoconf 2.59+ version, PHP 7.2 and above require 2.64+ version, and the PHP 7.2 phpize script requires 2.59+ version which are all greater than above mentioned 2.50 version therefore systems should be well supported by now. This patch was created with the help of autoupdate script: autoupdate <file> Reference docs: - https://www.gnu.org/software/autoconf/manual/autoconf-2.69/html_node/Obsolete-Macros.html - https://www.gnu.org/software/autoconf/manual/autoconf-2.59/autoconf.pdf
85 lines
2.7 KiB
Text
85 lines
2.7 KiB
Text
dnl config.m4 for extension sockets
|
|
|
|
PHP_ARG_ENABLE(sockets, whether to enable sockets support,
|
|
[ --enable-sockets Enable sockets support])
|
|
|
|
if test "$PHP_SOCKETS" != "no"; then
|
|
dnl Check for struct cmsghdr
|
|
AC_CACHE_CHECK([for struct cmsghdr], ac_cv_cmsghdr,
|
|
[
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <sys/types.h>
|
|
#include <sys/socket.h>]], [[struct cmsghdr s; s]])], [ac_cv_cmsghdr=yes], [ac_cv_cmsghdr=no])
|
|
])
|
|
|
|
if test "$ac_cv_cmsghdr" = yes; then
|
|
AC_DEFINE(HAVE_CMSGHDR,1,[Whether you have struct cmsghdr])
|
|
fi
|
|
|
|
AC_CHECK_FUNCS([hstrerror socketpair if_nametoindex if_indextoname])
|
|
AC_CHECK_HEADERS([netdb.h netinet/tcp.h sys/un.h sys/sockio.h errno.h])
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <sys/types.h>
|
|
#include <sys/socket.h>
|
|
]], [[static struct msghdr tp; int n = (int) tp.msg_flags; return n]])],[],
|
|
[AC_DEFINE(MISSING_MSGHDR_MSGFLAGS, 1, [ ])]
|
|
)
|
|
AC_DEFINE([HAVE_SOCKETS], 1, [ ])
|
|
|
|
dnl Check for fied ss_family in sockaddr_storage (missing in AIX until 5.3)
|
|
AC_CACHE_CHECK([for field ss_family in struct sockaddr_storage], ac_cv_ss_family,
|
|
[
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <sys/socket.h>
|
|
#include <sys/types.h>
|
|
#include <netdb.h>
|
|
]], [[struct sockaddr_storage sa_store; sa_store.ss_family = AF_INET6;]])],
|
|
[ac_cv_ss_family=yes], [ac_cv_ss_family=no])
|
|
])
|
|
|
|
if test "$ac_cv_ss_family" = yes; then
|
|
AC_DEFINE(HAVE_SA_SS_FAMILY,1,[Whether you have sockaddr_storage.ss_family])
|
|
fi
|
|
|
|
dnl Check for AI_V4MAPPED flag
|
|
AC_CACHE_CHECK([if getaddrinfo supports AI_V4MAPPED],[ac_cv_gai_ai_v4mapped],
|
|
[
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <netdb.h>
|
|
]], [[int flag = AI_V4MAPPED;]])],
|
|
[ac_cv_gai_ai_v4mapped=yes], [ac_cv_gai_ai_v4mapped=no])
|
|
])
|
|
|
|
if test "$ac_cv_gai_ai_v4mapped" = yes; then
|
|
AC_DEFINE(HAVE_AI_V4MAPPED,1,[Whether you have AI_V4MAPPED])
|
|
fi
|
|
|
|
dnl Check for AI_ALL flag
|
|
AC_CACHE_CHECK([if getaddrinfo supports AI_ALL],[ac_cv_gai_ai_all],
|
|
[
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <netdb.h>
|
|
]], [[int flag = AI_ALL;]])],
|
|
[ac_cv_gai_ai_all=yes], [ac_cv_gai_ai_all=no])
|
|
])
|
|
|
|
if test "$ac_cv_gai_ai_all" = yes; then
|
|
AC_DEFINE(HAVE_AI_ALL,1,[Whether you have AI_ALL])
|
|
fi
|
|
|
|
dnl Check for AI_IDN flag
|
|
AC_CACHE_CHECK([if getaddrinfo supports AI_IDN],[ac_cv_gai_ai_idn],
|
|
[
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <netdb.h>
|
|
]], [[int flag = AI_IDN;]])],
|
|
[ac_cv_gai_ai_idn=yes], [ac_cv_gai_ai_idn=no])
|
|
])
|
|
|
|
if test "$ac_cv_gai_ai_idn" = yes; then
|
|
AC_DEFINE(HAVE_AI_IDN,1,[Whether you have AI_IDN])
|
|
fi
|
|
|
|
PHP_NEW_EXTENSION([sockets], [sockets.c multicast.c conversions.c sockaddr_conv.c sendrecvmsg.c], [$ext_shared],, -DZEND_ENABLE_STATIC_TSRMLS_CACHE=1)
|
|
PHP_INSTALL_HEADERS([ext/sockets/], [php_sockets.h])
|
|
fi
|