mirror of
https://github.com/ruby/ruby.git
synced 2025-08-26 22:45:03 +02:00
a60831f9b6
When running on newer Intel processors supporting the feature, OpenBSD enforces indirect branch tracking. Without this endbr64 instruction, jumps to the coroutine_transfer function result in SIGILL on OpenBSD/amd64 when using such processors. The OpenBSD Ruby ports have been using a patch similar to this for the past two months. From some research, cet.h has been supported by GCC for about 6 years and LLVM for about 4 years.
60 lines
1.2 KiB
ArmAsm
60 lines
1.2 KiB
ArmAsm
##
|
|
## This file is part of the "Coroutine" project and released under the MIT License.
|
|
##
|
|
## Created by Samuel Williams on 10/5/2018.
|
|
## Copyright, 2018, by Samuel Williams.
|
|
##
|
|
|
|
#if defined(__OpenBSD__)
|
|
#include <cet.h>
|
|
#endif
|
|
|
|
#define TOKEN_PASTE(x,y) x##y
|
|
#define PREFIXED_SYMBOL(prefix,name) TOKEN_PASTE(prefix,name)
|
|
|
|
.text
|
|
|
|
.globl PREFIXED_SYMBOL(SYMBOL_PREFIX,coroutine_transfer)
|
|
PREFIXED_SYMBOL(SYMBOL_PREFIX,coroutine_transfer):
|
|
|
|
#if defined(__OpenBSD__)
|
|
_CET_ENDBR
|
|
#endif
|
|
|
|
# Make space on the stack for 6 registers:
|
|
subq $48, %rsp
|
|
|
|
# Save caller state:
|
|
movq %rbp, 40(%rsp)
|
|
movq %rbx, 32(%rsp)
|
|
movq %r12, 24(%rsp)
|
|
movq %r13, 16(%rsp)
|
|
movq %r14, 8(%rsp)
|
|
movq %r15, (%rsp)
|
|
|
|
# Save caller stack pointer:
|
|
movq %rsp, (%rdi)
|
|
|
|
# Restore callee stack pointer:
|
|
movq (%rsi), %rsp
|
|
|
|
# Restore callee state
|
|
movq 40(%rsp), %rbp
|
|
movq 32(%rsp), %rbx
|
|
movq 24(%rsp), %r12
|
|
movq 16(%rsp), %r13
|
|
movq 8(%rsp), %r14
|
|
movq (%rsp), %r15
|
|
|
|
# Adjust stack pointer back:
|
|
addq $48, %rsp
|
|
|
|
# Put the first argument into the return value:
|
|
movq %rdi, %rax
|
|
|
|
# We pop the return address and jump to it
|
|
ret
|
|
|
|
#if (defined(__linux__) || defined(__FreeBSD__)) && defined(__ELF__)
|
|
.section .note.GNU-stack,"",%progbits
|
|
#endif
|